arm64: preempt: Fix big-endian when checking preempt count in assembly

Commit 396244692232 ("arm64: preempt: Provide our own implementation of
asm/preempt.h") extended the preempt count field in struct thread_info
to 64 bits, so that it consists of a 32-bit count plus a 32-bit flag
indicating whether or not the current task needs rescheduling.

Whilst the asm-offsets definition of TSK_TI_PREEMPT was updated to point
to this new field, the assembly usage was left untouched meaning that a
32-bit load from TSK_TI_PREEMPT on a big-endian machine actually returns
the reschedule flag instead of the count.

Whilst we could fix this by pointing TSK_TI_PREEMPT at the count field,
we're actually better off reworking the two assembly users so that they
operate on the whole 64-bit value in favour of inspecting the thread
flags separately in order to determine whether a reschedule is needed.

Acked-by: Ard Biesheuvel <ard.biesheuvel@linaro.org>
Reported-by: "kernelci.org bot" <bot@kernelci.org>
Tested-by: Kevin Hilman <khilman@baylibre.com>
Signed-off-by: Will Deacon <will.deacon@arm.com>

diff --git a/arch/arm64/include/asm/assembler.h b/arch/arm64/include/asm/assembler.h
index ce985f13dce5d33f4fab1000a071f01c58a798b3..4feb6119c3c94840c459ceb3c328e67e60351688 100644 (file)
--- a/arch/arm64/include/asm/assembler.h
+++ b/arch/arm64/include/asm/assembler.h
@@ -722,11 +722,9 @@ USER(\label, ic    ivau, \tmp2)                    // invalidate I line PoU
        .macro          if_will_cond_yield_neon
 #ifdef CONFIG_PREEMPT
        get_thread_info x0
-       ldr             w1, [x0, #TSK_TI_PREEMPT]
-       ldr             x0, [x0, #TSK_TI_FLAGS]
-       cmp             w1, #PREEMPT_DISABLE_OFFSET
-       csel            x0, x0, xzr, eq
-       tbnz            x0, #TIF_NEED_RESCHED, .Lyield_\@       // needs rescheduling?
+       ldr             x0, [x0, #TSK_TI_PREEMPT]
+       sub             x0, x0, #PREEMPT_DISABLE_OFFSET
+       cbz             x0, .Lyield_\@
        /* fall through to endif_yield_neon */
        .subsection     1
 .Lyield_\@ :

diff --git a/arch/arm64/kernel/entry.S b/arch/arm64/kernel/entry.S
index c7d050207e5388b4a28bf6f6e762db8da958f5e1..763f03dc4d9e75cbef3ceb085ea7fe70d16a78d5 100644 (file)
--- a/arch/arm64/kernel/entry.S
+++ b/arch/arm64/kernel/entry.S
@@ -619,10 +619,8 @@ el1_irq:
        irq_handler
 
 #ifdef CONFIG_PREEMPT
-       ldr     w24, [tsk, #TSK_TI_PREEMPT]     // get preempt count
-       cbnz    w24, 1f                         // preempt count != 0
-       ldr     x0, [tsk, #TSK_TI_FLAGS]        // get flags
-       tbz     x0, #TIF_NEED_RESCHED, 1f       // needs rescheduling?
+       ldr     x24, [tsk, #TSK_TI_PREEMPT]     // get preempt count
+       cbnz    x24, 1f                         // preempt count != 0
        bl      el1_preempt
 1:
 #endif